求助变量路径%userprofile%

aa = aa & "本机电脑名称:" & Environ("computername") & vbCrLf aa = aa & "本机用户名称:" & Environ("username") & vbCrLf

Environ$("LOCALAPPDATA") 可以得到 C:\Users\(用户名)\AppData\Local\ 路径，这样用户名就不用获取了

AppData不建议直接设置，在Win XP下名字是Application Data，用Environ$("LOCALAPPDATA")才是对的，这个路径是系统设置的，不同电脑用户名变了，这个路径也会相应变化，如果要适应更多电脑系统的话。我以前搞过系统优化工具

没有LocalLow的路径变量
1.在Environ$("LOCALAPPDATA")得到后，用Replace替换
Replace(LCase$(Environ$("LOCALAPPDATA")), "local", "locallow")
2.上面的如果用户名或路径中带其他local就会出错,或者严谨一点可以这样
GetLocalLowPath(Environ$("LOCALAPPDATA"))
Private Function GetLocalLowPath(ByVal strLocalPath As String) As String
GetLocalLowPath = Left$(strLocalPath, InStrRev(strLocalPath, "\")) & "LocalLow"
End Function
3.还有一种就可以用SHGetKnownFolderPath得到，但是win xp不能用，这个函数在Vista以上才出现，xp下就会报无法定位

开了下虚拟机看了下xp的变量，发现之前的LOCALAPPDATA变量在xp下是没有的，在xp是APPDATA，如果要作兼容的话得用GetVersionEx得到系统的版本号来区分是xp还是xp以上的系统，分别调用Environ$("APPDATA")和Environ$("LOCALAPPDATA")

Option Explicit
Private Type GUID
Data1 As Long
Data2 As Integer
Data3 As Integer
Data4(0 To 7) As Byte
End Type
Private Declare Function SHGetKnownFolderPath Lib "shell32.dll" (rfid As Any, ByVal dwFlags As Long, ByVal hToken As Long, ppszPath As Long) As Long
Private Declare Function CLSIDFromString Lib "ole32.dll" (ByVal str As Long, id As GUID) As Long
Private Declare Function CoTaskMemFree Lib "ole32.dll" (ByVal pv As Long) As Long
Private Declare Function lstrcpy Lib "kernel32.dll" Alias "lstrcpyW" (ByVal lpString1 As Long, ByVal lpString2 As Long) As Long
Private Const AppDataLocalLowGUID = "{A520A1A4-1780-4FF6-BD18-167343C5AF16}"
Private Const MAX_PATH = 260
Private Sub Form_Load()
Debug.Print GetLocalLowPath
End Sub
Private Function GetLocalLowPath() As String
Dim stFID As GUID
Dim pPath As Long
Dim strPath As String
Call CLSIDFromString(StrPtr(AppDataLocalLowGUID), stFID)
Call SHGetKnownFolderPath(stFID, 0, 0, pPath)
strPath = Space$(MAX_PATH)
Call lstrcpy(StrPtr(strPath), pPath)
Call CoTaskMemFree(pPath)
GetLocalLowPath = Left$(strPath, InStr(strPath, vbNullChar) - 1)
End Function
'这个是调用SHGetKnownFolderPath函数得到LocalLow的路径，只适用Vista及以上系统的